cmake_minimum_required(VERSION 3.10)
project(blazeAravisSamples)

set(CMAKE_CXX_STANDARD 14)
add_compile_options(-Wall -Wextra -pedantic -Werror)

find_package(PkgConfig)
if (PkgConfig_FOUND)
    pkg_check_modules(ARAVIS IMPORTED_TARGET aravis-0.8>=0.8.26)
endif ()

if (NOT ARAVIS_FOUND)
    message(WARNING "No Aravis library found. Samples requiring Aravis will not be built.")
    return()
endif()

find_package(OpenCV QUIET COMPONENTS core highgui viz)

if (NOT OpenCV_FOUND)
    message(WARNING "No OpenCV found. Aravis sample will not be built.")
    return()
endif()

###
### AravisHelper
##
add_library(AravisHelper STATIC AravisHelper.h AravisCamera.h AravisCamera.cpp)
target_link_libraries(AravisHelper PUBLIC PkgConfig::ARAVIS opencv_core)

###
### BasicsSample
###
add_executable(BasicSample BasicSample.cpp)
target_link_libraries(BasicSample PRIVATE PkgConfig::ARAVIS AravisHelper opencv_core opencv_highgui)

###
### PointCloudSample
###
add_executable(PointCloudSample PointCloudSample.cpp)
target_link_libraries(PointCloudSample PRIVATE PkgConfig::ARAVIS AravisHelper opencv_core opencv_viz)

###
### PointCloudSample
###
add_executable(DistortionCorrectionSample DistortionCorrection.cpp)
target_link_libraries(DistortionCorrectionSample PRIVATE PkgConfig::ARAVIS AravisHelper opencv_core opencv_calib3d opencv_viz)

